Excelを利用したVBScriptの作り方

VBScriptを作るのにいきなりエディタで書き始めてもよいですが、あまり効率がよくありません。

そこでわたしはExcel 2000をエディタ代わりに使っています。 ExcelにはVBE（Visual Basic Editor）という機能があり、本来はVBAを作成するものですが、色々と便利なため、そこで作成したものをVBScript用に変更するということを行っています。

　

1

まずはExcelを立ち上げます。立ち上げたらVBEを開きます。

　

2

次に参照設定を開いて必要なコンポーネントにチェックを入れます。

　

わたしの知っているコンポーネントは以下の通りです。

InDesign
InDesign 2.0 Adobe InDesign 2.0J Type Library
InDesign CS(3.0) Adobe InDesign CS Type Library
InDesign CS2(4.0) Adobe InDesign CS2 Type Library
(1つだけチェックを入れればよい)
InDesign CS3(5.0) Adobe InDesign CS3 Type Library
InDesign CS4(6.0) Adobe InDesign CS4 Type Library
InDesign CS5(7.0) Adobe InDesign CS5 Type Library
（注）表示されない場合があります。
　→［参照設定でエラーが出る場合の対処法］
InDesign CS5.5(7.5) Adobe InDesign CS5.5 Type Library
（注）表示されない場合があります。
　→［参照設定でエラーが出る場合の対処法］
InDesign CS6(8.0) Adobe InDesign CS6 Type Library
（注）表示されない場合があります。
　→［参照設定でエラーが出る場合の対処法］
InDesign
CC(9.0)～2019(14.0)		 Adobe InDesign CC Type Library
（注）この間のバージョンのタイプライブラリ名は同じです。タイプライブラリ名をクリックすると「場所：」にファイル名が表示されますので、そこでフォルダ名（12.0-Jなど）を確認してください。
InDesign 2020(15.0) Adobe InDesign 2020 Type Library
Illustrator
Illustrator 10.0 Adobe Illustrator 10.0 Type Library
Illustrator CS(11.0) Adobe Illustrator 11.0 Type Library
Illustrator CS2(12.0) Adobe Illustrator CS2 Type Library
Illustrator CS3(13.0) Adobe Illustrator CS3 Type Library
（注）エラーがでる場合があります。
　→［参照設定でエラーが出る場合の対処法］
Illustrator CS4(14.0) Adobe Illustrator CS4 Type Library
Illustrator CS5(15.0) Adobe Illustrator CS5 Type Library
Illustrator
CS6(16.0)～2019(23.1)		 調査していません
Illustrator 2020(24.0) Adobe Illustrator 2020 Type Library
Photoshop
Photoshop CS2(9.0) Adobe Photoshop 9.0 Object Library
Photoshop CS3(10.0) Adobe Photoshop CS3 Object Library
Photoshop CS5(12.0) Adobe Photoshop CS5 Object Library
Photoshop
CS6(13.0)～CC2019(20.0)		 調査していません
Photoshop 2020(21.0) Adobe Photoshop 2020 Object Library

以上で準備は完了です。

　

3

わたしの場合、この後新しくモジュールを作成して、その中に記述していますが、特に必要というわけではありません。 また、オブジェクトブラウザとローカルウィンドウは必ず開いています。ローカルウィンドウはあとで説明します。

　

オブジェクトブラウザはコンポーネントの持っているプロパティなどを表示してくれます。検索もできます。

　

4

あとはひたすら記述していくのみです。

ただし、VBAで使用できてもVBScriptでは使用できないものがあるので注意が必要です。定数も10進数で記述しておく癖を付けた方がよいと思います。下はVBAではFormat(i,"00")としたいところですが、Format関数が使えないため、keta2という関数を自作した例です。

Sub sample()
    Dim app As InDesign.Application
    Dim doc As InDesign.Document
    Dim txf As InDesign.TextFrame
    Dim i As Integer, j As Integer
    Set app = CreateObject("InDesign.Application.CS2_J")
    Set doc = app.Documents.Add()
    With doc.ViewPreferences
        .HorizontalMeasurementUnits = 2053991795 'idMillimeters
        .VerticalMeasurementUnits = 2053991795
        .TextSizeMeasurementUnits = 2054255973 'idQ
    End With
    doc.DocumentPreferences.PageWidth = 210
    doc.DocumentPreferences.PageHeight = 297
    Set txf = doc.TextFrames.Add
    txf.GeometricBounds = Array(30, 10, 180, 200)
    txf.ParentStory.StoryPreferences.StoryOrientation _
        = 1986359924 '=idStoryHorizontalOrVertical.idVertical
    txf.ParentStory.PointSize = 60
    For i = 1 To 5
        j = txf.InsertionPoints.Count
        txf.InsertionPoints(j).Tatechuyoko = True
        txf.InsertionPoints(j).Contents _
            = keta2(Second(Now()))
        txf.InsertionPoints(j + 2).Tatechuyoko = False
        txf.InsertionPoints(j + 2).Contents = "秒<000d>"
    Next i
    doc.Save "c:\sample.indd"
    app.Quit
End Sub

Function keta2(i As Integer) As String
    If i < 10 Then
        keta2 = "0" & CStr(i)
    Else
        keta2 = CStr(i)
    End If
End Function

アプリケーションを動かすためには必ず各コンポーネントを呼び出す必要があります。呼び出すためにはCreateObjectを使います。それぞれのアプリケーションの記述は以下の通りです。

InDesign
InDesign 2.0 InDesign.Application.2
InDesign CS(3.0) InDesign.Application.CS
InDesign CS2(4.0) InDesign.Application.CS2_J
InDesign CS3(5.0) InDesign.Application.CS3_J
InDesign CS4(6.0) InDesign.Application.CS4_J
InDesign CS5(7.0) InDesign.Application.CS5_J
InDesign CS5.5(7.5) InDesign.Application.CS5.5_J
InDesign CS6(8.0) InDesign.Application.CS6_J
InDesign CC(9.0) InDesign.Application.CC_J
InDesign CC2014(10.0) InDesign.Application.CC.2014_J
InDesign CC2015(11.0) InDesign.Application.CC.2015_J
InDesign CC2017(12.0) InDesign.Application.CC.2017_J
InDesign CC2018(13.0) InDesign.Application.CC.2018
InDesign 2019(14.0) InDesign.Application.CC.2019
InDesign 2020(15.0) InDesign.Application.2020
InDesign 2021(16.0) InDesign.Application.2021
Illustrator
Illustrator 10.0 Illustrator.Application.1
Illustrator CS(11.0) Illustrator.Application.2
Illustrator CS2(12.0) Illustrator.Application.3
Illustrator CS3(13.0) Illustrator.Application.4
Illustrator CS4(14.0) Illustrator.Application.CS4
Illustrator CS5(15.0) Illustrator.Application.CS5
Illustrator CS6(16.0) Illustrator.Application.CS6
Illustrator CC(17.0) Illustrator.Application.CC
Illustrator CC2014(18.0) Illustrator.Application.CC.2014
Illustrator CC2015(19.0) Illustrator.Application.CC.2015
Illustrator CC2015.3(20.0) 未調査
Illustrator CC2017(21.0) Illustrator.Application.CC.2017
Illustrator CC2018(22.0) Illustrator.Application.CC.2018
Illustrator CC2019(23.0) Illustrator.Application.CC.2019
Illustrator 2020(24.0) Illustrator.Application.24
Illustrator 2021(25.0) Illustrator.Application.25
Photoshop
Photoshop CS2(9.0) Photoshop.Application.9
Photoshop CS3(10.0) Photoshop.Application.10
Photoshop CS5(12.0) Photoshop.Application.12
Photoshop.Application.12.1
Photoshop CS6(13.0) Photoshop.Application.60
Photoshop CC(14.0) Photoshop.Application.70
Photoshop CC2014(15.0) Photoshop.Application.80
Photoshop CC2015(16.0) Photoshop.Application.90
Photoshop CC2015.5(17.0) Photoshop.Application.100
Photoshop CC2017(18.0) Photoshop.Application.110
Photoshop CC2018(19.0) Photoshop.Application.120
Photoshop CC2019(20.0) Photoshop.Application.130
Photoshop 2020(21.0) Photoshop.Application.140
Photoshop.Application.140.1
Photoshop 2021(22.0) Photoshop.Application.150
Photoshop.Application.150.1

　

5

記述が完了したらデバッグを行います。エラーがあれば教えてくれます。また、このときローカルウィンドウでは生成されたオブジェクトの各プロパティの値を教えてくれるので、どういう状況なのか知ることができます。

　

6

いよいよ最終段階。完成したスクリプトを、エディタにコピー＆ペーストして、VBScript用に変更します。 このときVBAとVBScriptの違いを理解していないと、この作業はできませんので注意が必要です。

'Sub sample()
    Dim app 'As InDesign.Application
    Dim doc 'As InDesign.Document
    Dim txf 'As InDesign.TextFrame
    Dim i, j 'As Integer
    Set app = CreateObject("InDesign.Application.CS2_J")
    Set doc = app.Documents.Add()
    With doc.ViewPreferences
        .HorizontalMeasurementUnits = 2053991795 'idMillimeters
        .VerticalMeasurementUnits = 2053991795
        .TextSizeMeasurementUnits = 2054255973 'idQ
    End With
    doc.DocumentPreferences.PageWidth = 210
    doc.DocumentPreferences.PageHeight = 297
    Set txf = doc.TextFrames.Add
    txf.GeometricBounds = Array(30, 10, 180, 200)
    txf.ParentStory.StoryPreferences.StoryOrientation _
        = 1986359924 '=idStoryHorizontalOrVertical.idVertical
    txf.ParentStory.PointSize = 60
    For i = 1 To 5
        j = txf.InsertionPoints.Count
        txf.InsertionPoints(j).Tatechuyoko = True
        txf.InsertionPoints(j).Contents _
            = keta2(Second(Now()))
        txf.InsertionPoints(j + 2).Tatechuyoko = False
        txf.InsertionPoints(j + 2).Contents = "秒<000d>"
    Next 'i
    doc.Save "c:\sample.indd"
    app.Quit
'End Sub

Function keta2(i)
    If i < 10 Then
        keta2 = "0" & CStr(i)
    Else
        keta2 = CStr(i)
    End If
End Function

この場合、赤字のところが変更箇所。

　

7

変更が完了したら適当なファイル名をつけて、適当な場所に保存します。拡張子はvbsにする必要があります。

　

［HOME］